(using svnadmin dump)
After migrating from a Linux SVN server to a Windows server with Visual SVN, I needed a new backup script. Visual SVN doesn't come with a backup solution, but it does have enough SVN admin tools to be able to complete this task without having to install any additional SVN tools.
The scripts perform an svadmin dump on every repository on the server, then zip those dump files into a one zip file with the current date, using 7-zip. I used 2 scripts because I wanted to get as much logging as possible into the final zip file.
You’ll find loads of similar scripts throughout the web, the ones below are just my variant of other methods found; please feel free to cherry pick anything you need out of here. It goes without saying that you'll have to customize each script to get it work on your system. This code is free and comes with no guarantees.
Good luck!
Code Highlights:
These are conventions I felt were interesting, I've removed some of the script particulars:
Call svn_dump_repos.cmd > log.txt
- Calls the dump script and pipes the output to a text file (log_timestamp.txt)
Dir /A:D /B> dirs.txt
- (Run in Repository folder) Stores a list of all folders (repositories) into a text file (dirs.txt)
FOR /F %%r IN (dirs.txt) DO ( ... )
- Runs a loop for each item (%%r) in dirs.txt (i.e. each repository)
I highlighted the same lines that I felt were important in the code below.
Script 1:
svn_backup.cmd
@ECHO OFF
REM svn_backup.cmd
REM 02/10/2012 jmj
REM
REM This script will log the entire script: svn_dump_repos.cmd, and add it to the final zip file.
REM Instead of providing command-line arguments, each variable is set below.
REM
CLS
REM cpuname used for filename, workingdir for holding dumps/logs/etc,
REM and destdir for final destination
set cpuname=svnserver
set workingdir=D:\svn_backup\temp
set destdir=\\backup_server\DEV
REM timestamp = YYYYMMDD
set timestamp=%DATE:~-4%%DATE:~4,2%%DATE:~7,2%
REM Program file locations
set zipexe="C:\Program Files\7-Zip\7z.exe"
echo.
echo ****************************************************
echo Starting svn_dump_repos.cmd, (log as log_timestamp.txt)
echo ****************************************************
if not exist %workingdir% md %workingdir%
call svn_dump_repos.cmd > %workingdir%\log_%timestamp%.txt
REM svn_dump_repos.cmd created the final zip file, add any log files into it (*.txt)
echo.
echo ****************************************************
echo Adding log files to zip file
echo ****************************************************
cd %workingdir%
%zipexe% a %cpuname%_%timestamp%.zip %workingdir%\*.txt
echo.
echo ****************************************************
echo Move archive to final destination
echo ****************************************************
move *.zip %destdir%
echo.
echo ****************************************************
echo Removing the temporary files and exit
echo ****************************************************
del /f /q %workingdir%\*.txt
del /f /q %workingdir%\*.svndump
Script 2:
svn_dump_repos.cmd
@ECHO OFF
REM svn_dump_repos.cmd
REM 02/10/2012 jmj
REM
REM This script will perform a svnadmin dump on each repository in a folder
REM
REM Instead of providing command-line arguments, each variable is set below.
REM
REM cpuname used for filename, workingdir for holding dumps/logs/etc,
REM and destdir for final destination (not used here, but you want to include location in log)
set cpuname=svnserver
set repo=D:\Repositories
set workingdir=D:\svn_backup\temp
set destdir=\\backup_server\DEV
REM timestamp = YYYYMMDD
set timestamp=%DATE:~-4%%DATE:~4,2%%DATE:~7,2%
REM Program file locations
set svnadminexe="C:\Program Files\VisualSVN Server\bin\svnadmin"
set zipexe="C:\Program Files\7-Zip\7z.exe"
echo.
echo ****************************************************
echo Hello! Ready!
echo.
echo Create svn dump files for each repository on server
echo.
echo Using these Settings:
echo - Computer Name: %cpuname%
echo - Repository Folder: %repo%
echo - Working Directory: %workingdir%
echo - Destination Directory: %destdir%
echo - Zip Exe (7-zip) Location: %zipexe%
echo - svnadmin Location: %svnadminexe%
echo ****************************************************
echo.
echo.
echo ****************************************************
echo Dump Respositories (name_timestamp.svndump)
echo ****************************************************
cd %repo%
dir /A:D /B> %workingdir%\dirs.txt
cd %workingdir%
FOR /F %%r IN (%workingdir%\dirs.txt) DO (
echo Dumping: %%r
%svnadminexe% dump %repo%\%%r > %workingdir%\%%r_%timestamp%.svndump
if errorlevel 1 then Goto Error
)
echo.
echo ****************************************************
echo Compressing Dump files (servername_timestamp.zip)
echo ****************************************************
%zipexe% a -tzip %workingdir%\%cpuname%_%timestamp%.zip %workingdir%\*.svndump
if errorlevel 1 then Goto Error
echo.
echo ****************************************************
echo testing the new archive
echo ****************************************************
%zipexe% t %workingdir%\%cpuname%_%timestamp%.zip
if errorlevel 1 then Goto Error
echo.
echo ****************************************************
echo listing contents of new archive
echo ****************************************************
%zipexe% l %workingdir%\%cpuname%_%timestamp%.zip
if errorlevel 1 then Goto Error
GOTO Finish
:Error
echo.
echo There was an Error in the process
echo Please double-check the results!
echo.
echo GoodBye!
@ECHO ON
:Finish
echo.
echo Finished!
@ECHO ON
